Find ultimate state of moment-curvature

[ChiaTeHuang]

Dear all,

I'm doing the practice of moment-curvature from website example,
I want to find the difference between RC and R/ECC section,
so I change the concrete material to the properties of ECC,
the question is that: how could I find the ultimate state of moment-curvature?
cause we input the target ductility for analysis in the example, not to the ultimate state.
or when input the target ductility that can't converge,that's the ultimate curvature?
this is the code below, really appreciate if someone can answer!

Best wishes.

----------------------------------code start------------------------------------------------------

proc MomentCurvature {secTag axialLoad maxK {numIncr 100} } {
# Define two nodes at (0,0)
node 1 0.0 0.0
node 2 0.0 0.0

# Fix all degrees of freedom except axial and bending
fix 1 1 1 1
fix 2 0 1 0

# Define element
# tag ndI ndJ secTag
element zeroLengthSection 1 1 2 $secTag

# Create recorder
recorder Node -file sectionRECC.out -time -node 2 -dof 3 disp

# Define constant axial load
pattern Plain 1 "Constant" {
load 2 $axialLoad 0.0 0.0
}

# Define analysis parameters
integrator LoadControl 0.0
system SparseGeneral -piv; # Overkill, but may need the pivoting!
test NormUnbalance 1.0e-5 100
numberer Plain
constraints Plain
algorithm Newton
analysis Static

# Do one analysis for constant axial load
analyze 1

# Define reference moment
pattern Plain 2 "Linear" {
load 2 0.0 0.0 1.0
}

# Compute curvature increment
set dK [expr $maxK/$numIncr]

# Use displacement control at node 2 for section analysis
integrator DisplacementControl 2 3 $dK 1 $dK $dK

# Do the section analysis
analyze $numIncr
}


# units: kgf, cm
# Define model builder
# --------------------
model basic -ndm 2 -ndf 3

# Define materials for nonlinear columns
# ------------------------------------------
# ECC CONCRETE tag ftc etc ftp etp etu f'c e'c ecu alphaT,C betaT betaC
uniaxialMaterial ECC01 1 40.8 0.005 61.2 0.05 0.07 -408 -0.005 -0.012 5 1 2 1 0.4 0.3

# STEEL
# Reinforcing steel
set fy 4200.0; # Yield stress
set E 2040000.0; # Young's modulus
# tag fy E0 b
uniaxialMaterial Steel01 2 $fy $E 0.01

# Define cross-section for nonlinear columns
# ------------------------------------------

# set some paramaters
set colWidth 38.1
set colDepth 60.96

set cover 3.81
set As 3.87; # area of no. 7 bars

# some variables derived from the parameters
set y1 [expr $colDepth/2.0]
set z1 [expr $colWidth/2.0]

section Fiber 1 {

# Create the ECC fibers
patch rect 1 10 1 [expr -$y1] [expr -$z1] [expr $y1] [expr $z1]

# Create the reinforcing fibers (left, middle, right)
layer straight 2 3 $As [expr $y1-$cover] [expr $z1-$cover] [expr $y1-$cover] [expr $cover-$z1]
layer straight 2 2 $As 0.0 [expr $z1-$cover] 0.0 [expr $cover-$z1]
layer straight 2 3 $As [expr $cover-$y1] [expr $z1-$cover] [expr $cover-$y1] [expr $cover-$z1]

}

# Estimate yield curvature
# (Assuming no axial load and only top and bottom steel)
set d [expr $colDepth-$cover] ;# d -- from cover to rebar
set epsy [expr $fy/$E] ;# steel yield strain
set Ky [expr $epsy/(0.7*$d)]

# Print estimate to standard output
puts "Estimated yield curvature: $Ky"

# Set axial load
set P -81646.6

set mu 50; # Target ductility for analysis
set numIncr 100; # Number of analysis increments

# Call the section analysis procedure
MomentCurvature 1 $P [expr $Ky*$mu] $numIncr

[ashutoshsonpal]

I guess it depends on the material model you use for your analysis. Materials such as concrete01 continue the stress-strain curve even after the ultimate strain. Using other materials such as concrete04 for concrete and "Hysteretic" for steel can limit the ultimate values that the material can take. Your analysis will fail to converge when you use these materials, indicating the failure point.